        .386p
code32  segment para public use32
        assume cs:code32, ds:code32

include pmode.inc
include vrt.inc
include kb.inc
include v.inc
include grfx.inc

public  _end

;ħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħ
; DATA
;ħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħ

endpic          label   byte
include endpic.m

;ħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħ
; CODE
;ħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħħ

;°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°
; Put up ending screen
; Out:
;   EAX,EBX,ECX,EDX,ESI,EDI,EBP - ?
;°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°
_end:
        mov v86r_ax,10h
        mov al,10h
        int 33h
        mov dx,3dah
        in al,dx
        test al,8
        jz short $-3
        mov dx,3c0h
        xor ah,ah
endl0:
        mov al,ah
        out dx,al
        jmp short $+2
        out dx,al
        inc ah
        cmp ah,10h
        jb endl0
        mov al,20h
        out dx,al
        call _vrt_settimer

        mov edi,offset pal00+3
        lea esi,[edi+9]
        mov ecx,15
endl4:
        movsw
        movsb
        add esi,9
        loop endl4

        @vrt_setpalo 0,10h,_bpal

        @rlp edi,0a0000h
        mov esi,offset endpic
        mov dx,3ceh
        @outw 0ff08h
        mov dl,0c4h
        @outb 2
        inc edx
        mov ebx,350
endl5:
        mov al,1
endl5a:
        out dx,al
        mov ecx,20
        rep movsd
        sub edi,80
        shl al,1
        and al,0fh
        jnz endl5a
        add edi,80
        dec ebx
        jnz endl5

        mov _pals_ptr,offset pal00
        mov _pals_index,0
        mov _pals_len,10h
        mov _vrt_rout,offset _pals
endl1:
        cmp _vrt_rout,offset _ret
        jne endl1
        mov _vrt_timer,0
endl2:
        cmp _kbtbl1[1],0
        jne short endl2d
        cmp _vrt_timer,300h
        jb endl2
endl2d:
        mov _pals_ptr,offset _bpal
        mov _pals_index,0
        mov _pals_len,10h
        mov _vrt_rout,offset _pals
endl3:
        cmp _vrt_rout,offset _ret
        jne endl3

        ret

code32  ends
        end

