;@GOTO TRANSLATE

.586P


 INCLUDE ExD.INC
 
 INCLUDE ExDLdr.INC


_TEXT SEGMENT BYTE USE16 'CODE'
 ASSUME CS:_TEXT, DS:_TEXT, ES:_TEXT

 INCLUDE    LoadExD.msg

Install:
     MOV    AX,1600H
     INT    2FH
     CMP    AL,4
     JL     WinFailed

     MOV   BX,SP
     MOV   AX,SS
     MOV   CX,ES
     SUB   AX,CX
     SHR   BX,4
     ADD   BX,AX
     MOV   AH,4AH
     INT   21H
     JC    AllocErr

     CLD
     MOV   SI,80H
     LODSB
     CMP   AL,0
     JE    Usage
     MOVZX CX,AL
     SUB   DX,DX

PreName:
     LODSB
     CMP   AL,'"'
     JE    BeginName
     CMP   AL,' '
     JA    BeginName2
     LOOP  PreName
     JMP   OpenErr

BeginName2:
     DEC   SI
     MOV   DL, 1
BeginName:

     PUSH  SI
PostName:
     LODSB
     CMP   AL,'"'
     JE    EndName
     OR    DL,DL
     JE    PostName1
     CMP   AL,' '
     JBE   EndName
  PostName1:
     LOOP  PostName
     JMP   EndName2

EndName:
     DEC   SI
EndName2:
     MOV   BYTE PTR [SI],0

     MOV   AX,716CH
     SUB   BX,BX
     POP   SI
     PUSH  BX BX
     MOV   DL,1
     POP   CX DI
     INT   21H
     JC    OpenErr

     PUSH  CS
     POP   DS

     MOV   BX,AX
     LEA   DX,EXEHeader
     MOV   CX,LEXEHeader
     MOV   SI,DX
     MOV   AH,3FH
     INT   21H
     JC    ReadErr
     CMP   AX,CX
     JNE   ReadErr


     MOVZX EAX,WORD PTR [SI+4]
     MOVZX EDX,WORD PTR [SI+2]
     OR    DX,DX
     JE    SIZE0
     DEC   AX
    SIZE0:
     SHL   EAX,9
     ADD   EAX,EDX
     PUSH  EAX
     POP   DX CX
     MOV   AX,4200H
     INT   21H
     JC    SeekErr

     LEA   DX,EXEHeader
     MOV   CX,LAdamHeader
     MOV   SI,DX
     MOV   AH,3FH
     INT   21H
     JC    ReadErr
     CMP   AX,CX
     JNE   ReadErr 

     PUSH  BX
     MOV   EBX,[SI].AllExSize
     MOV   AH,48H
     ADD   EBX,15
     SHR   EBX,4
     INT   21H
     POP   BX
     JC    AllocErr

     PUSH  AX	      
     MOV   ExDFile, AX
     POP   BP

     NEG   CX
     SBB   DX,DX
     MOV   AX,4201H
     XCHG  CX,DX
     INT   21H
     JC    SeekErr

     SUB   DX,DX
     JMP   BeginRead
NextPartOfFile:
     ADD   BP,0FFFH
BeginRead:
     MOV   ECX,0FFF0H
     MOV   EAX,CS:[SI].AllExSize
     CMP   EAX,ECX
     JGE   OkCX
     XCHG  AX,CX
OkCX:
     MOV   AH,3FH
     MOV   DS,BP
     CWDE
     INT   21H
     JC    ReadErr
     SUB   CS:[SI].AllExSize,EAX
     JNLE  NextPartOfFile

     MOV   AH,3EH
     INT   21H
     JC    CloseErr


;-------------------------------------------------------------------------------

     PUSH   CS
     POP    DS

     MOV    AX,1687H
     INT    2FH
     OR     AX,AX
     JNE    PMFailed

     PUSH   ES	DI
     POP    GoDPMI

     MOV    BX,SI
     MOV    AH,48H
     INT    21H
     JC     AllocErr

     MOV    ES,AX

IFDEF IntroMessage
     LEA    SI, IntroMessage
     CALL   WriteIt
ENDIF

     SUB    AX,AX
     CALL   GoDPMI
     JC     PMFailed

     MOV    AX,168AH
     LEA    SI,VendorID
     INT    2FH
     CMP    AL,8AH
     JNE    DPMISuccess

PMFailed:
     JMP    DPMIFailed

DPMISuccess:
     PUSH   ES DI
     POP    GetLDTAlias

     SUB    AX,AX
     MOV    CX,1
     INT    31H
     JC     PMFailed
     MOV    GateSel,AX
     MOV    DI,100H
     AND    AL,NOT 7
     XCHG   AX,DI

     CALL   GetLDTAlias
     JC     PMFailed

     VERW   AX
     JNE    PMFailed

     MOV    ES,AX

IF   NOTASKSWITCH  EQ  YES
     MOV    AX,1681H
     INT    2FH
ENDIF

     CLD
     MOV    EAX,LoaderSegment
     SHL    EAX,4
     ;ADD    EAX,OFFSET LDRStart
     STOSW
     MOV    AX, Rg0FlatCodeSelector
     STOSW
     MOV    AX, 0EC00H
     STOSD

     MOV    AX,1234H
     ExDFile  EQU WORD PTR $-2
	    DB 066H
	    DB 09AH
    GetLDTAlias LABEL DWORD
    GoDPMI  DD 0
    GateSel DW 0

     PUSHF

IF   NOTASKSWITCH  EQ YES
     MOV    AX,1682H
     INT    2FH
ENDIF

     MOV    AX,1
     MOV    BX,GateSel
     INT    31H

     POPF
     JNC    SuccQuitIt

IFDEF MessageError
     LEA    SI, MessageError
     CALL   WriteIt
ENDIF
     MOV    AL, Rg0ErrorExitCode
     JMP    QuitIt

SuccQuitIt:
IFDEF MessageSuccess
     LEA    SI, MessageSuccess
     CALL   WriteIt
ENDIF
     MOV    AL, SuccessExitCode

QuitIt:
    .EXIT

WriteIt     PROC NEAR
     CLD
     MOV    AH,02
 WriteItNext:
     LODSB
     CMP    AL,ETX
     JE     WriteItQuit
     MOV    DL,AL
     INT    21H
     JMP    WriteItNext
 WriteItQuit:
     RET
WriteIt     ENDP



;-------------------------------------------------------------------------------

WriteError:
     PUSH  CS
     POP   DS
     PUSH  AX SI
     LEA   SI,PreError
     CALL  WriteIt
     POP   SI
     CALL  WriteIt
     POP   AX
    .EXIT  

AllocErr:
     LEA   SI, MemoErr
DOSRetCode:
     MOV   AL, DOSErrorExitCode
     JMP   WriteError

OpenErr:
SeekErr:
ReadErr:
CloseErr:
     LEA   SI, FileErr
     JMP   DOSRetCode

WinFailed:
     LEA   SI, WinNotP
WinRetCode:
     MOV   AL, WinErrorExitCode
     JMP   WriteError


DPMIFailed:
     LEA   SI, DPMIErr
     JMP   WinRetCode

Usage:
     LEA   SI, Using
     JMP   DOSRetCode


     VendorID	DB "MS-DOS",0

     EXEHeader   LABEL

_TEXT ENDS

_STACK SEGMENT STACK
 DB 512 DUP (?)
_STACK ENDS

END Install


:TRANSLATE
@ECHO OFF
TASM /m /q /i..\Include\ LoadExD.BAT
LINK386	      LoadExD.OBJ 
DEL           LoadExD.OBJ

