;Constants for ExDLdr

     NONO                 EQU  00H  
     YES                  EQU  01H   
     ETX                  EQU  03H        ;end of text

;file related
     FileMark             EQU  "madA"     ;DOS32 executable Header Sign
     LEXEHeader           EQU  06H        ;needed for determining MZ size
     LAdamHeader          EQU  2CH        ;DOS32 Header Size

;exit codes
     SuccessExitCode      EQU  -0         
     DOSErrorExitCode     EQU  -1         ;DOS service failed
     WinErrorExitCode     EQU  -2         ;Windows or DPMI service failed
     Rg0ErrorExitCode     EQU  -3         ;Loader or Init part of ExD failed


LoaderSegment	 SEGMENT PARA USE32 'CODE'    ;DO NOT CHANGE!

    ASSUME       CS:LoaderSegment, DS:LoaderSegment, ES:LoaderSegment

    DOS32Header  STRUC
       HeadMark  DD ?
       DVersion  DW ?
                 DW ?
       ImageSize DD ?   
       AllExSize DD ?   
       ImageOff  DD ?
       DOS32EIP  DD ?
       HeapAlloc DD ?
       DOS32ESP  DD ?
       ReloOff   DD ?
                 DD ?
                 DD ?
    DOS32Header  ENDS

LDRStart:
	PUSH	 DS ES
	MOV	 CX,Rg0FlatDataSelector
	MOV	 DS,ECX
	MOV	 ES,ECX
	MOVZX	 EAX,AX
	SHL	 EAX,4
	CMP	 [EAX].HeadMark,FileMark
	JNE	 FailRet
	MOV	 EDI,EAX
	MOV	 EBX,EAX
	MOV	 EDX,[EAX].ImageOff
	MOV	 EAX,[EAX].DOS32ESP
	ADD	 EBX,EDX  

	VMMCall  _HeapAllocate EAX, HEAPZEROINIT
	TEST	 EAX,EAX
	JE	 FailRet

	MOV	 EBP,EAX

	MOV	 ESI,[EDI].ReloOff  
	CLD
	VMMCall  _lmemcpy  EAX, EBX, ESI   

	MOV	 ECX,[EDI].ImageSize
	MOV	 EDX,EAX
	ADD	 ECX,EBX
	ADD	 ESI,EBX

DynaLink1:
	SUB	 EAX,EAX
DynaLink2:
	CMP	 ESI,ECX
	JAE	 DynaLink6
	LODSB
	TEST	 AL,1
	JZ	 DynaLink3
	SHL	 EAX,7
	JMP	 DynaLink2
DynaLink3:
	SHR	 EAX,1
	ADD	 EDX,EAX
	CMP	 ESI,ECX
	JE	 DynaLink4a
	LODSB
	OR	 AL,AL
	JE	 DynaLink5
DynaLink4:
	DEC	 ESI
DynaLink4a:
	ADD	 [EDX],EBP
	JMP	 DynaLink1

DynaLink5:
	MOV	 [EDX],DS
	JMP	 DynaLink1

DynaLink6:
        MOV      EAX, [EDI].DOS32EIP
        ADD      EAX,EBP
	CALL	 EAX           ;preserve EBP
        JC       FailRet0
	POP	 ES  DS
	RETF

FailRet0:
	VMMCall  _HeapFree  EBP, 0
FailRet:
	POP	 ES  DS
	STC
	RETF

LoaderSegment	 ENDS
