;@GOTO TRANSLATE

 INCLUDE TstRDTSC.inc
 INCLUDE ExD.inc
 INCLUDE ExDLdr.inc

.MODEL TINY
.586P

.CODE
.STARTUP

MOV  SP,300H
MOV  AX,DS
MOV  S1,AX
MOV  S2,AX
MOV  S3,AX

MOV AH,9
LEA DX,Intro
INT 21H

MOV BX,SP
MOV AH,4AH
SHR BX,4
INT 21H
JC  RunFailed

MOV AX,4B00H
LEA BX,EXEC
LEA DX,FNAME
INT 21H
JC  RunFailed
MOV AH,4DH
INT 21H
CMP AL, SuccessExitCode
JNE RunFailed

MOV  BX, Supported 
SUB  ECX,ECX
NOP
DB  0FH, 33H
NOP

MOV AH,9

Here:
SHL BX,1
MOV AH,9 
MOV DX, Strings[BX]
INT 21H

.EXIT

RunFailed:
 MOV    BX,3
 JMP    Here

EXEC    DW 0
        DW 80H
     S1 DW 0
        DW 5CH
     S2 DW 0
        DW 6CH
     S3 DW 0

Strings DW OFFSET Suppo, OFFSET Emula, OFFSET NotSupp, OFFSET DOSfa
FNAME   DB 'TstRDPMC.exd',0
Intro   DB 13,10,'<<<<< RDPMC tester by EliCZ  (386+ CPU, for Win9x only) >>>>>'
        DB 13,10,'Tests presence and V86 mode restriction of RDPMC instruction.'
        DB 13,10,13,10,'>>>>> Instruction RDPMC is ',36
Suppo   DB "supported.",36
Emula   DB "supported, but disabled in V86 mode for ever.",36
NotSupp DB "not supported.",36
DOSfa   DB "DOS failed!",7,36

 
  

END


:TRANSLATE
SET APP=TsRDPMC
TASM /M /Q /T %APP%.bat  /I..\..\Include /I. /I..\..\ExDLoad
TLINK /3/x/t  %APP%, TstRDPMC
DEL %APP%.OBJ
SET APP=