;@GOTO TRANSLATE

.586P
.MODEL FLAT

 INCLUDE EXD.INC

 INCLUDE TstRDTSC.INC

.CODE

TotalStart:
        _RDTSC  EQU  330FH

Uninst:
	LEA   ESI,MainInt06
	MOV   EAX,06
	VMMCall UnHook_V86_Fault              
                                              
	LEA   ESI,MainInt13
	MOV   EAX,13
	VMMCall UnHook_V86_Fault              

	PUSH  0 OFFSET TotalStart             
        MOV    AX, Client_SS * 256 + Client_ESP
        VMMCall Map_Flat

        XCHG  EAX,EDI   
	LEA   ESI,QuitCode
	MOV   ECX,QuitCodeL
	CLD
	SUB   EDI,ECX
	PUSH  EDI
	REP   MOVSB                          
	RET   

      QuitCode:
	VMMCall _HeapFree
	ADD   ESP,8                           
      Quit:
	POPAD
	POPFD
      UnInstFailed:
	RET
      QuitCodeL EQU $-QuitCode

;-------------------------------------------------------------------------------

	JMP	MainINT13             ;EB 06  (can be EB 0A too)

      Chain13:
	JMP	PrevHook13            ;FF 25 AdrOfPrev
                                      ;Hook will fill [AdrOfPrev] 

      MainINT13:                      ;handler begins here!!!
	PUSHFD
	PUSHAD

        LEA     EDI, NotMe13
        CALL    CheckIt

        JMP     Cont0

        MOV      CL,100B
        MOV     EAX,CR4
        TEST     AL,CL
        JE      Cont0
        NOT     ECX
        AND      AL,CL
        JMP     Quit

     Cont0:
        ADD     [EBP].Client_EIP, 2
        MOV     WORD PTR [EBP].Client_EBX, Emulated
        JMP     Uninst

     NotMe13:                         
	POPAD
	POPFD
	JMP	Chain13               

;-------------------------------------------------------------------------------

	JMP	MainINT06             ;EB 06  (can be EB 0A too)

      Chain06:
	JMP	PrevHook06            ;FF 25 AdrOfPrev
                                      ;Hook will fill [AdrOfPrev] 

      MainINT06:                      ;handler begins here!!!
	PUSHFD
	PUSHAD
        LEA     EDI, NotMe06
        CALL    CheckIt
        ADD     [EBP].Client_EIP, 2
        MOV     WORD PTR [EBP].Client_EBX, NotSupported
        JMP     Uninst

     NotMe06:  
	POPAD
	POPFD
	JMP	Chain06               

;-------------------------------------------------------------------------------
CheckIt:
        CMP     EBX, CurVM
        JNE     NotMe

        MOV     AX, Client_CS * 256 + Client_EIP
        VMMCall Map_Flat
        CMP     EAX, -1
        JE      NotMe

        CMP     WORD PTR [EAX],_RDTSC
        JNE     NotMe

        RET

     NotMe:
        POP     EAX
        JMP     EDI
;-------------------------------------------------------------------------------

Start:
	VMMCall Get_Cur_VM_Handle
        MOV     CurVM, EBX

	LEA     ESI,MainINT06
	MOV     EAX,06
	VMMCall Hook_V86_Fault
        JC      InitFailed

	LEA     ESI,MainINT13
	MOV     EAX,13
	VMMCall Hook_V86_Fault
   InitFailed:
        RET

.DATA
        CurVM       DD ?
	PrevHook06  DD ?
	PrevHook13  DD ?

.STACK	4

END Start

:TRANSLATE
@ECHO OFF
REM   CALL .BAT   PathToExDLoad PathToExDLoad ThisFolder PathToInclude
CALL  ExDLdr.bat ..\..\ExDLoad .\ ..\..\Include
SET APP=TstRDPMC
TASM  /M /T /Q /I..\..\Include %APP%.BAT
DLINK -SExDLdr %APP%, %APP%.exd 
DEL            %APP%.obj
DEL            ExDLdr.exe
SET APP=