;
;                                Dir en assembleur þ
;                                þþþþþþþþþþþþþþþþþþþ
;                              Kaid/ACiX pour ACiX-M nø3

.model tiny
.code
.386
org 100h
start:

        mov ah,1ah              ;D‚finie la DTA
        lea dx,dta
        int 21h

;--------------- D‚but de la proc‚dure de recherche des fichiers -------------

        mov ah,4eh              ;On recherche tous les fichiers du
        mov cx,27h              ; r‚pertoire courant
        lea dx,fichiers
        int 21h


findnext:

        mov ah,9                ;Affiche le nom du fichier
        lea dx,[dta+30]
        int 21h

        call aff_taille_heure_date ;Affiche taille, heure et date

        lea di,[dta+30]         ;DI pointe sur le nom du fichier ds la DTA
        mov cx,12               ;Il y a 12 caractŠres au total
        mov al,' '              ;On les remplace par des espaces
        rep stosb               ;Effectue le remplacement

        inc nb_fichiers         ;Incr‚mente le nombre de fichiers

;------------------------------- FindNext ----------------------------------

        mov ah,4fh              ;Recherche le prochain fichier
        int 21h

        jnc findnext            ;S'il y a encore un fichier, on boucle

        
        mov ax,nb_fichiers      ;Met dans AX le nombre de fichiers
        lea di,[nb_fich+6]      ;DI pointe sur le dernier caractŠre         
        mov cx,5                ;AX est un word, il y a 5 chiffres
        call decode_decimal     ;On 'd‚code'

        lea di,[nb_fich+2]      ;DI pointe sur le 1ø caractŠre 
        call kill_zero          ;Cette proc‚dure permet de remplacer les '0' par des ' '

        mov ah,9                ;On affiche le nombre de fichiers
        lea dx,nb_fich
        int 21h


        int 20h                 ;Quitte le programme


aff_taille_heure_date:

;------------------- On commence par prendre la taille -----------------------

        mov eax,dword ptr [dta+26] ;Met ds EAX la taille du fichier
        mov cx,10               ;Nombre de chiffres 
        lea di,[infos+11]       ;DI pointe sur le dernier caractŠre         

        call decode_decimal     ;Routine qui 'decode' les nombres d‚cimaux

        lea di,[infos+2]        ;DI pointe sur le 1ø caractŠre
        call kill_zero          ;Cette proc‚dure permet de remplacer les '0' par des ' '

;----------------------- On s'attaque … l'heure  ----------------------------

        mov ax,word ptr [dta+16h]  ;Met ds AX l'heure 'packt‚e'
        push ax                 ;Sauve AX 2 fois
        push ax

;On s'occupe d'abors des secondes

        and ax,0000000000011111b ;Garde les 5ø bits de AX
        shl ax,1                ;<=> … AX*2
        lea di,[infos+31]       ;DI pointe sur la fin de la string
        mov cx,2                ;0<AX<60, il y a 2 chiffres 
        call decode_decimal     ;Routine qui 'decode' les nombres d‚cimaux


;puis des minutes

        pop ax                  ;Restaure AX
        shr ax,5                ;On d‚cale AX de 5 bits vers la dte
        and ax,0000000000111111b ;On garde les 6ø bits de AX
        call decode_decimal     ;Routine qui 'decode' les nombres d‚cimaux

;et enfin de l'heure

        pop ax                  ;Restaure AX
        shr ax,11               ;On d‚cale AX de 11 bits vers la dte        
        call decode_decimal     ;Routine qui 'decode' les nombres d‚cimaux


;------------------------- Et puis … la date ---------------------------------

        mov ax,word ptr [dta+18h]  ;Met ds AX la date 'packt‚e'
        push ax                 ;Sauve AX deux fois
        push ax

;On commence par les ann‚es

        shr ax,9                ;On d‚cale AX de 9 bits vers la dte        
        add ax,80               ;On ajoute 80 par avoir les ann‚es
        lea di,[infos+21]       ;DI pointe sur la fin de la string
        call decode_decimal     ;Routine qui 'decode' les nombres d‚cimaux


;ensuite on a les mois

        pop ax                  ;Restaure AX
        shr ax,5                ;On d‚cale AX de 5 bits vers la dte
        and ax,0000000000001111b ;On garde les 4ø bits de AX
        call decode_decimal     ;Routine qui 'decode' les nombres d‚cimaux


;et pr finir, les jours

        pop ax                  ;Restaure AX
        and ax,0000000000011111b ;On garde les 5ø bits de AX
        call decode_decimal     ;Routine qui 'decode' les nombres d‚cimaux


        mov ah,9                ;On affiche la string 'infos'
        lea dx,infos
        int 21h
        ret


decode_decimal:

        push cx                 ;Sauve CX
        mov ebx,10              ;EBX=10

aff_dec:
        xor edx,edx             ;Met EDX … 0, car il va contenir le reste
        div ebx                 ;On divise EAX par EBX

        add dl,30h              ;On ajoute 48 … DL pour obtenir la valeur ASCII du reste
        mov ds:[di],dl          ;On place DL dans la string
        dec di                  ;On d‚cr‚mente DI

        loop aff_dec            ;On boucle tant qu'il y a des chiffres … afficher <=> CL<>0
        
        pop cx                  ;Restaure CX
        dec di                  ;D‚cremente DI
        ret                     ; et quitte


kill_zero:

;------------------ Remplace les z‚ros inutiles par des espaces -------------

        mov cx,9                ;On efface un maximun de 9 z‚ros
        mov al,' '              ;On remplace ces z‚ros par des espaces

killing_time:
        stosb                   ;Remplace l'octet contenu ds ES:[DI] par AL

        cmp byte ptr es:[di],'0' ;Si ce n'est pas un z‚ro, on quitte la
        jne plus_de_zero         ;proc‚dure

        loop killing_time       ;Loop

plus_de_zero:
        ret        



fichiers        db '*.*',0
dta             db 43 dup (?),'$'
infos           db '  0000000000  00/00/00  00:00:00',10,13,'$'
nb_fichiers     dw 0
nb_fich         db 10,13,5 dup (?),' fichier(s)$'
whoami          db 'Kaid/ACiX'
end start
