.MODEL SMALL
.STACK 50h

.DATA
  X       DB 40                ; Le couple ( X, Y ) forme les coordonn‚es
  Y       DB 13                ; de la balle.
  DirX    DB 1                 ; Sens de d‚placement: dirX=1 => on va … droite,
  DirY    DB 1                 ; dirX=-1 => … gauche, dirY=1 => on descend et
                                 ; dirY=-1 => on monte
  RegCom EQU 03FCh             ; On utilise com1

.CODE                        

       mov AX, @data           ; Transmission du segment de donn‚es … DS
       mov DS, AX             

       mov AX, 0003h           ; On efface l'‚cran en fixant le mode texte
       int 10h               

       mov AH, 0Fh             ; Cette interruption transmet le num‚ro de
       int 10h                 ;   page active dans BH


 Boucle:                         ; D‚but de la boucle

       mov AH, 0AH             ; On affiche le caractŠre
       mov AL, 0AH             ; en code ASCII, en d‚cimal : 10 =>
       mov CX, 1               ; A en h‚xad‚cimal
       int 10h                                     

       call pause              ; Appel de la routine qui marque une pause

       cmp BX, 01h
       jnz Suite
        call DELon
        inc BX
       Suite:

       cmp BX, 00h
       jz Suite2
        inc BX
       Suite2:


       cmp BX, 08h
       jnz Suite3
        xor BX, BX
        call DELoff
       Suite3:     

       mov AH, 0AH             ; On efface le caractŠre pr‚c‚demment
       mov AL, 20h             ; affich‚, en affichant un espace
       mov CX, 1                
       int 10h

       mov AL, x               ; Coordonn‚e … traiter dans AL 
       mov AH, 79              ; Limite sup‚rieure ds AH
       mov DL, dirx            ; Coef directeur dans DL
       call calc               ; Appel de la routine qui traite les coordonn‚es
       mov x, AL               ; On met ds X la nvelle coordonn‚e (AL)
       mov dirx, DL            ; et la nvelle direction ds Dirx


       mov AL, y               ; Coordonn‚e … traiter ds AL 
       mov AH, 24              ; Limite sup‚rieure ds AH
       mov DL, diry            ; Coef directeur ds DL
       call calc               ; Appel de la routine qui traite les coordonn‚es
       mov y, AL               ; On met ds Y la nvelle coordonn‚e (AL)
       mov diry, DL            ; et la nvelle direction ds Diry


       mov AH, 02              ; Positionne le curseur … ( 1, 1 )
       mov DL, x               ; On met X dans DL
       mov DH, y               ; On met Y dans DH
       int 10h


       in AL, 60h              ; On lit le port clavier
       cmp AL, 01h             ; Echap press‚ ?
       jne boucle              ; Non, on continue 

       mov DX, RegCom
       mov AL, 00d             ; On ‚teint la DEL en mettant
       out DX, AL              ;  DTR … 0
         
       mov AX, 4C00h           ; On quitte le programme sans planter le PC...
       int 21h

 pause:                        ; D‚but de la boucle   
       mov CX, 5               ; | Pause de deux boucles imbriqu‚es pour
 partie1:                        
       push CX                 ; |   pouvoir voir le curseur...
       mov CX, 0FFFFh          ; | 
 partie2:                        
       loop partie2            ; |
       pop CX                  ; |
       loop partie1            ; |
       ret                     ; Retourne au programme principal

  DELon:
      push DX
      push AX
      mov DX, RegCom
      mov AL, 01d              ; On allume la DEL en mettant
      out DX, AL               ;  DTR … 1
      pop AX
      pop DX
      ret

  DELoff:
      push DX
      push AX
      mov DX, RegCom
      mov AL, 00d              ; On ‚teint la DEL en mettant
      out DX, AL               ;  DTR … 0
      pop AX
      pop DX
      ret                                
  calc:

 ;R‚sum‚ du contenu des registres:
 ; AL contient la coordonn‚e (X ou Y)
 ; AH contient la limite sup‚rieure … le pas d‚passer (79 pr X et 24 pr Y) 
 ; DL contient le coef directeur (Dirx ou Diry)

       cmp AL,0                 ; AL est nul ?
       je sort_inf              ; On est sortie de l'‚cran 

       cmp AL,AH                ; AL est ‚gAL … AH (lim sup‚rieur de l'‚cran)
       je sort_sup              ; On sort aussi de l'‚cran 

       jmp ok                   ; On a 0<AL<AH, pas de prob

 sort_inf:                       

       mov DL,1                 ; AL doit augmenter, le coef devient positif
       mov BX, 01h              ; On d‚cide d'allumer la DEL...
       jmp ok                   ; C'est bon
        
 sort_sup:

       mov DL,-1                ; AL doit diminuer, le coef devient n‚gatif
       mov BX, 01h              ; On d‚cide d'allumer la DEL...

 ok:

      add AL, DL                ; On ajoute … la coordonn‚e le coef
      ret                       ; Retourne au programme principal

 END
