;Starfield 3d en mode 13h
;by Nithril/ACiX


;Simplifie la frappe

w EQU word ptr
b EQU byte ptr

.MODEL TINY
.CODE
.386
ORG 100h

Start:

;----------------Initialise les etoiles------------------
        lea ebx,buf
        mov cx,3000
init:
        push cx

        ;-----x-----    ;entre -300 et 300
        mov cx,600
        call random
        sub dx,300
        mov [ebx],dx

        ;-----y-----    ;entre -300 et 300
        mov cx,600
        call random
        sub dx,300
        mov [ebx+2],dx

        ;-----z-----
        mov cx,8190     ;2^13 utile pour le and
        call random
        ;inc dx
        mov [ebx+4],dx


        add ebx,8
        pop cx
loop init

;------------------------end-------------------------



        mov ax,13h      ;on entre dans le mode 13h
        int 10h

        mov ax,0a000h   ;es pointe sur le segment de la mem video
        mov es,ax

principale:


        lea esi,buf
        mov ecx,1000     ;Starfield de 500 etoiles
sub_loop:

        mov di,[esi+6]      ;ancien offset du pixel allum‚ precedement
        xor al,al
        stosb               ;on l'eteind

        movzx ebx,w [esi+4]  ;on dec le z
        dec ebx
        and ebx,8191         ;z cyclique   8191 = 0001111111111111b
        mov [esi+4],bx       ;je pense que vous connaissez le and
        inc ebx              ;pour evitez que z=ebx=0 => division par zero


        movsx eax,w [esi]    ;on projete  X
        sal eax,9
        cdq
        idiv ebx
        add eax,160
        cmp eax,320
        jae skipit           ;x clipping
        mov edi,eax


        movsx eax,w [esi+2]  ;on projete Y
        sal eax,9
        cdq
        idiv ebx
        add eax,100
        cmp eax,200          ;y clipping
        jae skipit

        shl eax,6            ;calcul l'offset
        add edi,eax          ;eax=y
        shl eax,2            ;edi=x
        add edi,eax          ;eax*64+eax*64*2 +edi
                             ;eax*(64+64*2)   +edi
                             ;eax*320+edi
                             ;2 shl sont plus rapides qu'un mul


        mov [esi+6],di       ;sauvegarde l'offset du pixel qu'on allume
        mov al,20            ;avec une couleur de 20
        stosb                ;es:[di]=al



        skipit:
        add esi,8            ;prochaine etoile
        dec ecx
jnz sub_loop

        mov ecx,1            ;a changer suivant votre PC
        temporisation:
        imul eax,ecx,50
        loop temporisation



        in al,60h   ;echap presse
        cmp al,1
jne principale


        mov ax,3h   ;on revient au mode texte
        int 10h


        int 20h     ;on quitte


;La procedure de nombre aleatoire
;Merci a je sais plus qui
random:
    mov     ax,Seed
    add     ax,1234
    xor     al,ah
    rol     ah,1
    add     ax,4321
    ror     al,1
    xor     ah,al
    mov     Seed,ax
    xor     dx,dx
    div     cx
ret

seed dw ?
buf dw 30000 dup(?)  ;le buffer de nos etoiles


;structur du buffer:
;8 bytes par etoiles:
;0-1: X
;2-3: Y
;4-5: Z
;6-7: Offset
end start

