DECLARE FUNCTION Jeu% (mot$)
DECLARE SUB Pause ()
DECLARE FUNCTION BodyPart% (partie%)
DECLARE FUNCTION WriteWord% (mot$, lettres$)
DECLARE SUB PRINTY (texte$, ligne%, colonne%, caracteres%, fond%)
DECLARE FUNCTION Center$ (Chaine$, largeur%)
DECLARE FUNCTION LisLesMots% (Word$())
DEFINT A-Z

DIM Words(1 TO 200) AS STRING

max = LisLesMots(Words())
 
DO
  RANDOMIZE TIMER
  mot$ = Words(RND * (max - 1) + 1)

  Rester = Jeu(mot$)

LOOP WHILE Rester

COLOR 15, 0
CLS
SYSTEM

DATA ABAJOUE,ABAQUE,ABJECTS,ABRICOT,ABYSSE,ACAJOU,ACIERA,ACQUIT,AGNELIN
DATA AIEULE,AIOLI,AKUAVIT,ASHRAMS
DATA BICEPS,BOBARD,BOXER,BRADYPE,BRAHMANE
DATA CAJOU,CHEIRE,CHYLE,CLOWN,COALTAR,CSARDAS,CYANOSE,CZARS
DATA DANCING,DAZIBAO,DIVAGUER,DJELLABA,DRYADES,DYNASTIE
DATA EBAHIR,EMBARGO,ETAYER,EUSTACHE,EXAMENS
DATA FAZENDA,FIABLE,FIXATIF,FOETAUX,FRAGILE,FRUITS
DATA GABEGIE,GAZODUCS,GENDARME,GEYSER,GIGOGNE,GNOCCHIS
DATA HUARTS,HYADES,HYDROMEL
DATA IAMBIQUE,ICAQUES,ICHTYOL,IDIOME,IDYLLE,IGNIVOME,ILION,INJURES
DATA JAVELOT,JOYAUX
DATA KABYLE,KYSTIQUE
DATA LABIUM,LABRITS,LACRYMAL,LAPILLI,LOBES,LUCRATIF,LUNDI,LYMPHES
DATA MACABRES,MAIGRES,MAJORAT,MARYLAND,MAZAGRAN,MERDEUX,MIGNARDE,MISOGYNE
DATA MIXTION,MOERE,MONTUEUX,MORFIL,MOYENS,MULARDES,MUPHTI,MUSCARI,MYIASE
DATA NANZOUK,NAUFRAGE,NERPRUN,NIAOULI,NIOBIUM,NITRITES,NOIRAUD,NOYAIT
DATA NUCALE,NYMPHE
DATA OCTAVES,OESTRAL,ONCQUES,OPTIQUE,ORGANDI,ORTEILS
DATA PALMAIRE,PARAFER,PARJURER,PAYANTS,PENDU,PHAETONS,PHLOX,PLANCTON
DATA POLYPE,PSCHENT,RAPHIDE
DATA RHOMBE,RIESLING,RIMAYES,ROGNURES,RORQUAL,ROWING
DATA SAMARIUM,SAOULS,SATYRE,SAYONS,SCYTHES,SEXTUOR,SKIER,SOUDAGE,SPATH
DATA STYLITE,SULTAN,SVASTIKA,SVELTE,SVELTES,SWASTIKA,SWEATER,SWING,SYBARITE
DATA SYZYGIES
DATA TERBIUM,TEXTES,THERMOS,TUBARDS,TYPHUS
DATA VERTICAL,VEXANTES,VIZIR,VORTEX
DATA WALKYRIE,ZYTHUM
DATA #

FUNCTION BodyPart (partie)

  COLOR , 6
  SELECT CASE partie
    CASE 0: FOR i = 4 TO 22: PRINTY SPACE$(34), i, 3, 0, 0: NEXT
    CASE 1: PRINTY SPACE$(24), 21, 5, -1, -1
    CASE 2: FOR i = 5 TO 20: PRINTY "  ", i, 10, -1, -1: NEXT
    CASE 3: PRINTY SPACE$(22), 5, 10, -1, -1
    CASE 4: PRINTY "º", 6, 27, 6, 0
    CASE 5: PRINTY "ß     ß", 7, 24, 0, 1
            PRINTY "       ", 8, 24, -1, -1
            PRINTY "Ü     Ü", 9, 24, -1, -1
    CASE 6: PRINTY "ßß   ßß", 10, 24, 0, 2
            FOR i = 11 TO 14: PRINTY "         ", i, 23, -1, -1: NEXT
    CASE 7: FOR i = 15 TO 18: PRINTY "  ÛÛÛ  ", i, 24, 0, 3: NEXT
    CASE 8: FOR i = 11 TO 14
              PRINTY " ", i, 21, 0, 3
              PRINTY " ", i, 33, 0, 3
            NEXT
            PRINTY "ßß", 10, 22, -1, -1
            PRINTY "ßß", 10, 31, -1, -1
    CASE 9: PRINTY "Ü", 15, 33, 0, 4
            PRINTY "Ü", 15, 21, -1, -1
            PRINTY "  ÛÛÛ  ", 19, 24, -1, -1
            PRINTY ". .", 7, 26, 14, 1
            PRINTY "I", 8, 27, -1, -1
            PRINTY "/\", 9, 26, -1, -1
            BodyPart = 1
  END SELECT

END FUNCTION

FUNCTION Center$ (Chaine$, largeur)
 
  Chaine$ = SPACE$(largeur \ 2) + Chaine$ + SPACE$(largeur \ 2)
  Center$ = MID$(Chaine$, (LEN(Chaine$) - largeur + 2) \ 2, largeur)

END FUNCTION

FUNCTION Jeu (mot$)

DO
  lettres$ = "' " + LEFT$(mot$, 1)
  IF RIGHT$(mot$, 1) <> LEFT$(mot$, 1) THEN lettres$ = lettres$ + RIGHT$(mot$, 1)
 
  COLOR 14, 1: CLS
  etat = BodyPart(0)
  PRINTY Center$("<-: Pendu :->", 80), 1, 1, 14, 5
  PRINTY "Lettres d‚j… propos‚es :", 13, 40, 14, 1
  PRINTY "Mot … trouver :", 4, 40, 14, 1
  PRINTY "1    Nouveau mot", 19, 40, 14, 1
  PRINTY "2    Recommencer", 20, 40, 14, 1
  PRINTY "0    Quitter", 21, 40, 14, 1

  DO

    PRINTY LEFT$(lettres$ + SPACE$(38), 38), 15, 40, 11, 3
    Trouve = WriteWord(mot$, lettres$)

    DO: k$ = UCASE$(INKEY$): LOOP WHILE k$ = ""
   
    SELECT CASE k$

      CASE "1": etat = 3
      CASE "2": etat = 4
      CASE "0": EXIT DO
    
      CASE "A" TO "Z":
        i = INSTR(lettres$, k$)
        IF i > 0 THEN
          PRINTY k$, 15, i + 39, 30, 4
          PRINTY Center$("Lettre d‚j… propos‚e", 38), 16, 40, 14, 4
          Pause
          PRINTY SPACE$(38), 16, 40, 14, 1
        ELSE
          lettres$ = lettres$ + k$
          IF INSTR(mot$, k$) = 0 THEN
            PENDU = PENDU + 1
            etat = BodyPart(PENDU)
          ELSE
            IF Trouve + 1 = LEN(mot$) THEN etat = 2
          END IF
        END IF

    END SELECT

  LOOP WHILE etat = 0

LOOP WHILE etat = 4
   
Trouve = WriteWord(mot$, lettres$ + "ABCDEFGHIJKLMNOPQRSTUVWXYZ")
IF etat = 2 THEN
  PRINTY Center$("Bravo !", 38), 10, 40, 14, 0
  Pause
ELSEIF etat = 1 THEN
  PRINTY Center$("Vous ˆtes mort !", 38), 10, 40, 12, 0
  Pause
END IF
 
Jeu = etat <> 0
 
END FUNCTION

FUNCTION LisLesMots (Word$())

  max = LBOUND(Word$)
  DO
    READ Word$(max)
    IF Word$(max) = "#" THEN EXIT DO ELSE max = max + 1
  LOOP UNTIL max > UBOUND(Word$)

  LisLesMots = max - 1

END FUNCTION

SUB Pause

DO: k$ = INKEY$: LOOP WHILE k$ = ""

END SUB

SUB PRINTY (texte$, ligne, colonne, caracteres, fond)

  IF fond >= 0 THEN COLOR , fond
  IF caracteres >= 0 THEN COLOR caracteres
  IF ligne > 0 THEN LOCATE ligne
  IF colonne > 0 THEN LOCATE , colonne
  IF texte$ <> "" THEN PRINT texte$;

END SUB

FUNCTION WriteWord (mot$, lettres$)
 
  FOR i = 1 TO LEN(mot$)
    IF INSTR(lettres$, MID$(mot$, i, 1)) > 1 THEN
         PRINTY " " + MID$(mot$, i, 1) + " ", 6, 36 + i * 4, 15, 2
         Trouve = Trouve + 1
    ELSE PRINTY " . ", 6, 36 + i * 4, 12, 4
    END IF
  NEXT

  WriteWord = Trouve

END FUNCTION

